Plotten von Datensätzen mit Gnuplot in .eps

[NextFall]

Hier treibt sich nicht zufälligerweise ein Gnuplot Guru rum oder? Verzweifel gerad so nen bisschen und irgendwie komm ich mit der Doku und sonstigen Infos die ich im Netz finde nicht mehr weiter.

Möchte Daten aus einer Datei plotten. Der Datensatz sieht prinzipiell so aus

0.00E+00 1.00E+02 0.00E+00 0.00E+00
6.00E+00 3.30E+01 5.99E+01 7.08E+00
1.20E+01 1.09E+01 6.92E+01 1.99E+01
1.80E+01 3.59E+00 6.37E+01 3.27E+01
2.40E+01 1.18E+00 5.47E+01 4.41E+01
3.00E+01 3.91E-01 4.59E+01 5.37E+01
3.60E+01 1.29E-01 3.81E+01 6.17E+01
4.20E+01 4.25E-02 3.16E+01 6.84E+01
4.80E+01 1.40E-02 2.61E+01 7.39E+01
5.40E+01 4.63E-03 2.15E+01 7.85E+01
6.00E+01 1.53E-03 1.78E+01 8.22E+01

So sieht mein Ansatz aus für die Ausgabe

# Plot von Ru-107
#=====================

# Ausgabedatei und -format
set term postscript eps enhanced color
set output 'Ru-107_10x6min.eps'

# Achsen und Gitternetz
set title 'Decay Ru-107, 10x6 minutes'
set xrange [0:60]
set xtics 0,10
set yrange [0:100]
set ytics 0,20
set xlabel 'time in minutes'
set ylabel 'part of nuclide'

# Legende
set key on
set key outside bottom center box

# Sonstiges
#set samples 300

# Plot
plot\
'Ru-107_10x6min.txt' title 'Ru-107' using 1:2 lw 3 lc 16 smooth splines,\
'Ru-107_10x6min.txt' title 'Rh-107' using 1:3 lw 3 lc 16 smooth splines,\
'Ru-107_10x6min.txt' title 'Pd-107' using 1:4 lw 3 lc 16 smooth splines

Kriege dann als Fehler " "...\Ru-107_10x6min_2.plt", line 31: ';' expected ". In der Ausgabe ist nur der Plot des ersten Datensatzes zu finden und das auch nur mit Darstellung der Punkte ohne splines.

Jemand zufällig ne Idee?

[NextFall]

Falls es jemanden auch nochmal betreffen sollten, ich habs gelöst
Hab das title an der falschen Stelle eingefügt und da war Gnuplot dann ein wenig eigen. Doku nochmals lesen hilft

'Ru-107_10x6min.txt' using 1:2 title 'blub' lw 3 lc 16 smooth splines,\